Intro
Ceci est le challenge n°22 d'une série de challenges Excel créés spécialement pour découvrir modern Excel et booster vos compétences afin d'atteindre le niveau d'expert !
Rappel : qu'est-ce que le "modern Excel" ?
C'est une version du logiciel disponible avec Microsoft 365 proposant beaucoup de nouveautés.
Par exemple, on trouve de nombreuses nouvelles fonctions (RECHERCHEX,FILTRE, UNIQUE, MAP, etc.) très utiles ainsi qu'un mode de fonctionnement dynamique des résultats depuis une formule source (en savoir plus sur la propagation des formules Excel ici).
Ces nouveautés, intégrées au reste du logiciel, rendent Excel beaucoup plus pratique et efficace qu'auparavant.
Pour en savoir plus sur le modern Excel, tu peux cliquer ici.
Objectif du challenge
Dans ce challenge, l'objectif est de récupérer la liste de tous les vendredis 13 de l'année actuelle (l'année 2023 à la publication du challenge).
Tu peux télécharger le fichier correspondant en bas de cette page. Pour t'aider tu peux aussi regarder la vidéo sur youtube.
Ce challenge doit être réussi en utilisant une seule formule dans une seule cellule : la cellule D5
Le défi en plus : battre notre champion-maison, Martin qui a réussi ce challenge en utilisant 51 caractères !
Ce que tu dois faire
Avec une seule formule dans la cellule D5 : récupérer la liste de tous les vendredis 13 de l'année actuelle
Attention aux contraintes
Important : pour booster tes compétences dans le modern Excel, tu dois réussir ce challenge avec une seule formule saisie dans une seule cellule, sans étendre ta formule initiale vers le bas.
Ceci te permettra de pratiquer la propagation de résultats depuis une formule initiale.
La cellule à compléter est la cellule F5, qui doit produire sans être étendue autant de résultats que nécessaires.
Tu veux te challenger encore plus ? Essaye de faire autant, voire encore moins, que le record à battre d'une formule de 51 caractères.
Maintenant, à toi de jouer !
La formule étape par étape pour obtenir ces résultats
#1 Initialiser
Générer une première plage composée de la liste des dates de l'année en cours.
=SEQUENCE(365;;DATE(2023;1;1))
#2 Actualiser
Automatiser le fonctionnement de la liste à la date actuelle.
=SEQUENCE(365;;DATE(ANNEE(AUJOURDHUI());1;1))
#3 Filtrer
Ne garder que les vendredi dans la liste de date en filtrant les résultat par un LET.
=LET(s;SEQUENCE(365;;DATE(ANNEE(AUJOURDHUI());1;1));FILTRE(s;TEXTE(s;"jjj-j")="ven-13"))
La formule finale en 88 caractères
=LET(s;SEQUENCE(365;;DATE(ANNEE(AUJOURDHUI());1;1));FILTRE(s;TEXTE(s;"jjj-j")="ven-13"))
La formule finale en 72 caractères
=LET(s;DATE(ANNEE(AUJOURDHUI());SEQUENCE(12);13);FILTRE(s;JOURSEM(s)=6))
La formule finale en 50 caractères
=LET(s;"13/"&LIGNE(1:12);FILTRE(s;JOURSEM(s)=6))*1
Les fonctions et symboles importants utilisés
LET
Permet de créer une ou plusieurs variables pour simplifier une formule.
SEQUENCE
Permettre de générer une liste de nombre séquentiels dans un tableau.
DATE
Pour gérer les erreurs renvoyées lors d'un calcul en les remplaçant.
Chaque semaine, Solpedinn te propose un nouveau challenge pour booster tes compétences Excel ! N'hésite pas à tester les autres challenges.
