Intro
Ceci est le défi n°15 challenge d'une série de challenges Excel créés spécialement pour découvrir modern Excel et booster vos compétences afin d'atteindre le niveau d'expert !
Rappel : qu'est-ce que le "modern Excel" ?
C'est une version du logiciel disponible avec Microsoft 365 proposant beaucoup de nouveautés.
Par exemple, on trouve de nombreuses nouvelles fonctions (RECHERCHEX,FILTRE, UNIQUE, MAP, etc.) très utiles ainsi qu'un mode de fonctionnement dynamique des résultats depuis une formule source (en savoir plus sur la propagation des formules Excel ici).
Ces nouveautés, intégrées au reste du logiciel, rendent Excel beaucoup plus pratique et efficace qu'auparavant.
Pour en savoir plus sur le modern Excel, tu peux cliquer ici.
Objectif du challenge
Dans ce challenge, l’objectif est d'obtenir un tirage aléatoire et conditionnel sans doublon d'une liste.
Tu peux télécharger le fichier correspondant en bas de cette page. Pour t'aider tu peux aussi regarder la vidéo sur Youtube.
Ce challenge doit être réussi en utilisant une seule formule dans une seule cellule : la cellule G5
Le défi en plus : battre notre champion-maison, Martin qui a réussi ce challenge en utilisant 92 caractères !
Ce que tu dois faire
Avec une seule formule dans la cellule G5 :
Générer un ordre aléatoire à partir de la liste de noms indiquée en colonne B avec une condition et sans répétition (cf. résultats dans la colonne I en vert).
Attention à la contrainte suivante : la plage à indiquer est "B5:B18" et "C5:C18" (ou "B5:C18")
Important : pour booster tes compétences dans le modern Excel, tu dois réussir ce challenge avec une seule formule saisie dans une seule cellule, sans étendre ta formule initiale vers le bas.
Ceci te permettra de pratiquer la propagation de résultats depuis une formule initiale.
La cellule à compléter est la cellule F5, qui doit produire sans être étendue autant de résultats que nécessaires.
Tu veux te challenger encore plus ? Essaye de faire autant, voire encore moins, que le record à battre d'une formule de 92 caractères.
Maintenant, à toi de jouer !
La formule étape par étape pour obtenir ces résultats
#1 Exclure
Depuis la liste de candidats, appliquer un filtre afin d'exclure les candidats non admissibles.
=FILTRE(B5:B18;C5:C18="Oui")
#2 Encadrer
Mettre les résultats obtenus dans un tableau via la fonction LET.
=LET(t;FILTRE(B5:B18;C5:C18="Oui");t)
#3 Assembler (optionnel)
Ajouter à notre liste de candidats admissibles un premier empilement de tableaux (ajouter une colonne si besoin).
=LET(t;FILTRE(B5:B18;C5:C18="Oui");ASSEMB.H(t;t))
#4 Assembler
Ajouter à notre liste de candidats admissibles une série de valeurs aléatoires via un empilement de tableaux.
=LET(t;FILTRE(B5:B18;C5:C18="Oui");ASSEMB.H(t;TABLEAU.ALEA(NBVAL(t))))
#5 Trier
Trier l'assemblage via l'insertion d'un outil pour lister dynamiquement notre liste de candidat.
=LET(t;FILTRE(B5:B18;C5:C18="Oui");TRIER(ASSEMB.H(t;TABLEAU.ALEA(NBVAL(t)));2))
#6 Sélectionner
Conserver visuellement que la première colonne de notre empilement et les les cinq premières lignes.
=LET(t;FILTRE(B5:B18;C5:C18="Oui");PRENDRE(TRIER(ASSEMB.H(t;TABLEAU.ALEA(NBVAL(t)));2);;1))
La formule finale en 92 caractères
=LET(t;FILTRE(B5:B18;C5:C18="Oui");PRENDRE(TRIER(ASSEMB.H(t;TABLEAU.ALEA(NBVAL(t)));2);;1))
Les fonctions et symboles importants utilisés
FILTRE
Pour sélectionner certaines données en suivant des critères spécifiques.
ASSEMB.H
Pour assembler plusieurs plages ensemble dans un même tableau dans l'ordre des colonnes.
LET
Permet de créer une ou plusieurs variables pour simplifier une formule.
PRENDRE
Pour renvoyer un nombre spécifié de lignes ou de colonnes contiguës à partir du début ou de la fin d’un tableau.
Tu en découvriras beaucoup plus sur toutes ces fonctions et leurs possibilités en te testant au fur et à mesure des challenges.
